圖片

周末有位一又友問(wèn)起Heikiun Ashi決策，那時(shí)在外地沒(méi)如何講演，今天在這里與全球系數(shù)共享文采版與MT4版源碼的不同，有有趣有趣學(xué)編寫(xiě)決策的一又友系數(shù)來(lái)探討下。

Heikiun Ashi決策Heikiun Ashi決策稱(chēng)平均棒圖或平滑燭炬圖，通過(guò)設(shè)想每個(gè)時(shí)候周期的開(kāi)盤(pán)價(jià)、最高價(jià)、最廉價(jià)和收盤(pán)價(jià)，生成新的燭炬圖，以更明晰地展現(xiàn)價(jià)錢(qián)趨勢(shì)。這種決策有助于過(guò)濾市集雜音，突顯主要趨勢(shì)，提議用于大周期看趨勢(shì)。Heikiun Ashi決策并不提議單獨(dú)行為期貨、外匯粗略黃金的來(lái)去決策的依據(jù)，投資者應(yīng)當(dāng)與其他時(shí)刻分析決策、基本面分析和市集熱枕等要素相議論，進(jìn)行概括判斷。MT4版塊

圖片

文采6版塊

圖片

源  碼  下方共享的Heikiun Ashi決策源碼為主圖K線樣子，是闡述常見(jiàn)的樣貌改寫(xiě)。僅行為戰(zhàn)略念念路拓展，不提議徑直用于期貨等投資實(shí)盤(pán)中（投資有風(fēng)險(xiǎn)，入市須嚴(yán)慎）。來(lái)去員不錯(cuò)闡述艾云戰(zhàn)略所提供的決策源碼，議論閑居的來(lái)去告誡進(jìn)行改編，釀成我方的來(lái)去戰(zhàn)略。

文采版：適用于文采6、7、8等軟件

M:=3;XXOPEN:=(REF(OPEN,M)+REF(CLOSE,M))/2;XXCLOSE:=(HIGH+LOW+CLOSE+OPEN)/4;XXHIGH:=MAX1(XXOPEN,XXCLOSE,HHV(HIGH,M));XXLOW:=MIN1 (XXOPEN,XXCLOSE,LLV(LOW,M));STICKLINE(XXCLOSE>XXOPEN,XXCLOSE ,XXOPEN ,8,1 ),COLORRED;DRAWLINE(XXCLOSE>XXOPEN,XXHIGH ,XXCLOSE>XXOPEN,XXCLOSE,COLORRED );DRAWLINE(XXCLOSE>XXOPEN,XXOPEN ,XXCLOSE>XXOPEN,XXLOW ,COLORRED);STICKLINE(XXCLOSE<=XXOPEN,XXCLOSE ,XXOPEN ,8,0 ),COLORFFFF66;DRAWLINE(XXCLOSE<=XXOPEN,XXOPEN ,XXCLOSE<=XXOPEN,XXHIGH,COLORFFFF66);DRAWLINE(XXCLOSE<=XXOPEN,XXCLOSE ,XXCLOSE<=XXOPEN,XXLOW,COLORFFFF66);

MT4版:

#property indicator_chart_window

#property indicator_buffers 4

#property indicator_color1 Red

#property indicator_color2 White

#property indicator_color3 Red

#property indicator_color4 White

#property indicator_width1 1

#property indicator_width2 1

#property indicator_width3 3

#property indicator_width4 3

//---

input color ExtColor1 = Red;    // Shadow of bear candlestick

input color ExtColor2 = White;  // Shadow of bull candlestick

input color ExtColor3 = Red;    // Bear candlestick body

input color ExtColor4 = White;  // Bull candlestick body

//--- buffers

double ExtLowHighBuffer[];

double ExtHighLowBuffer[];

double ExtOpenBuffer[];

double ExtCloseBuffer[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//|------------------------------------------------------------------|

void OnInit(void)

  {

   IndicatorShortName("Heiken Ashi");

   IndicatorDigits(Digits);

//--- indicator lines

   SetIndexStyle(0,DRAW_HISTOGRAM,0,1,ExtColor1);

   SetIndexBuffer(0,ExtLowHighBuffer);

   SetIndexStyle(1,DRAW_HISTOGRAM,0,1,ExtColor2);

   SetIndexBuffer(1,ExtHighLowBuffer);

   SetIndexStyle(2,DRAW_HISTOGRAM,0,3,ExtColor3);

   SetIndexBuffer(2,ExtOpenBuffer);

   SetIndexStyle(3,DRAW_HISTOGRAM,0,3,ExtColor4);

   SetIndexBuffer(3,ExtCloseBuffer);

//---

   SetIndexLabel(0,"Low/High");

   SetIndexLabel(1,"High/Low");

   SetIndexLabel(2,"Open");

   SetIndexLabel(3,"Close");

   SetIndexDrawBegin(0,10);

   SetIndexDrawBegin(1,10);

   SetIndexDrawBegin(2,10);

   SetIndexDrawBegin(3,10);

//--- indicator buffers mapping

   SetIndexBuffer(0,ExtLowHighBuffer);

   SetIndexBuffer(1,ExtHighLowBuffer);

   SetIndexBuffer(2,ExtOpenBuffer);

   SetIndexBuffer(3,ExtCloseBuffer);

//--- initialization done

  }

//+------------------------------------------------------------------+

//| Heiken Ashi                                                      |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   int    i,pos;

   double haOpen,haHigh,haLow,haClose;

//---

   if(rates_total<=10)

      return(0);

//--- counting from 0 to rates_total

   ArraySetAsSeries(ExtLowHighBuffer,false);

   ArraySetAsSeries(ExtHighLowBuffer,false);

   ArraySetAsSeries(ExtOpenBuffer,false);

   ArraySetAsSeries(ExtCloseBuffer,false);

   ArraySetAsSeries(open,false);

   ArraySetAsSeries(high,false);

   ArraySetAsSeries(low,false);

   ArraySetAsSeries(close,false);

//--- preliminary calculation

   if(prev_calculated>1)

      pos=prev_calculated-1;

   else

     {

      //--- set first candle

      if(open[0]<close[0])

        {

         ExtLowHighBuffer[0]=low[0];

         ExtHighLowBuffer[0]=high[0];

        }

      else

        {

         ExtLowHighBuffer[0]=high[0];

         ExtHighLowBuffer[0]=low[0];

        }

      ExtOpenBuffer[0]=open[0];

      ExtCloseBuffer[0]=close[0];

      //---

      pos=1;

     }

//--- main loop of calculations

   for(i=pos; i<rates_total; i++)

     {

      haOpen=(ExtOpenBuffer[i-1]+ExtCloseBuffer[i-1])/2;

      haClose=(open[i]+high[i]+low[i]+close[i])/4;

      haHigh=MathMax(high[i],MathMax(haOpen,haClose));

      haLow=MathMin(low[i],MathMin(haOpen,haClose));

      if(haOpen<haClose)

        {

         ExtLowHighBuffer[i]=haLow;

         ExtHighLowBuffer[i]=haHigh;

        }

      else

        {

         ExtLowHighBuffer[i]=haHigh;

         ExtHighLowBuffer[i]=haLow;

        }

      ExtOpenBuffer[i]=haOpen;

      ExtCloseBuffer[i]=haClose;

     }

//--- done

   return(rates_total);

  }

//+------------------------------------------------------------------+

艾云戰(zhàn)略網(wǎng)站kaiyun.com

 https://www.aiycl.cn溫馨指示：投資有風(fēng)險(xiǎn)，入場(chǎng)需嚴(yán)慎！ 本站僅提供存儲(chǔ)辦事，掃數(shù)推行均由用戶發(fā)布，如發(fā)現(xiàn)存害或侵權(quán)推行，請(qǐng)點(diǎn)擊舉報(bào)。